Upload from Zoho Creator File Upload field to OpenAI Vector Store

Upload from Zoho Creator File Upload field to OpenAI Vector Store

I’ve struggled for quite a while to get this working properly.

For a long time we relied on Azure Functions as a workaround to handle file transfers between Zoho Creator and OpenAI Vector Stores. It worked, but added unnecessary infrastructure and complexity.

After a lot of trial and error, I finally got a fully working, direct solution using:

  • Zoho Creator invokeurl

  • Creator file download API

  • OpenAI Files API

  • OpenAI Vector Store API

No external middleware required.

Below is the working function.

  1. map SaveUploadToVectorStore(string report_link_name, string record_id, string filename, string vector_store_id)
  2. {
  3. // Download a file from current app
  4. download_url = "https://creator.zoho.eu/api/v2" + zoho.appuri + "report/" + report_link_name + "/" + record_id + "/File_upload/download";

  6. downloaded_file = invokeurl
  7. [
  8. url :download_url
  9. type :GET
  10. connection:"zohocreator"
  11. ];

  13. // Ensure correct filename
  14. downloaded_file.setFileName(filename);

  16. // Upload to OpenAI
  17. multipart_parts = List();
  18. multipart_parts.add({"paramName":"purpose","content":"assistants","stringPart":"true"});
  19. multipart_parts.add({"paramName":"file","content":downloaded_file});

  21. upload_resp = invokeurl
  22. [
  23. url :"https://api.openai.com/v1/files"
  24. type :POST
  25. connection:"openai_connection"
  26. files:multipart_parts
  27. ];

  29. file_id = "";
  30. if(upload_resp != null && upload_resp.containKey("id"))
  31. {
  32. file_id = upload_resp.get("id");
  33. }

  35. // Attach to vector store
  36. if(file_id != "")
  37. {
  38. attach_headers = Map();
  39. attach_headers.put("Content-Type","application/json");
  40. attach_headers.put("OpenAI-Beta","assistants=v2");

  42. attach_body = Map();
  43. attach_body.put("file_id", file_id);

  45. invokeurl
  46. [
  47. url :"https://api.openai.com/v1/vector_stores/" + vector_store_id + "/files"
  48. type :POST
  49. connection:"openai_connection"
  50. headers:attach_headers
  51. parameters:attach_body.toString()
  52. ];
  53. }

  55. result = Map();
  56. result.put("file_id", file_id);

  58. return result;
  59. }

Key prerequisites

For this to work, you need:

  1. A Zoho Creator OAuth connection

    • Must have permission to download files from your app.

    • Used in the invokeurl download call.

    • Example link name: "zohocreator"

  2. An OpenAI API Key connection

    • Connection type: API Key

    • Header:
      Authorization = Bearer <your_openai_key>

    • Example link name: "openai_connection"

  3. Correct region

    • Adjust creator.zoho.eu if you are using .com, .in, etc.

  4. Correct report link name

    • The report must expose the File Upload field.

  5. Use actualname
    Zoho prepends a unique ID to uploaded files.
    Use:

    filename = input.File_upload.actualname;

    This removes the internal prefix and ensures the correct file extension (e.g. .pdf) is preserved.
    Without this, OpenAI may receive the file as "content" and reject it with File type not supported.